Asymptote is a powerful vector graphics language designed for creating mathematical diagrams and figures. It can output images in either eps or pdf format, and is compatible with the standard mathematics typesetting language, LaTeX. It is also a complete programming language, and has cleaner syntax than its predecessor, MetaPost, which was a language used only for two-dimensional graphics.

Here is an example of an image that can be produced using Asymptote:

In a sense, Asymptote is the ruler and compass of typesetting.
You can use Asymptote on the AoPSWiki right now, by enclosing the Asymptote code within <asy>...</asy> tags. For example, the following code

<asy>
draw((0,0)--(3,7),red);
dot((0,0));
dot((3,7));
label("Produced with Asymptote "+version.VERSION,point(S),2S);
</asy>

created the picture

And on the AoPS forums you can use [asy]..[/asy]

[asy]
draw((0,0)--(3,7),red);
dot((0,0));
dot((3,7));
label("Produced with Asymptote "+version.VERSION,point(S),2S);
[/asy]

See also

• LaTeX
• AoPS’s Getting Started with LaTeX guide.
• Asymptote Forum on AoPS

Next: Getting Started

To get started using Asymptote, it’s a good idea to go through this guide in the following steps:

1. Follow the instructions on the Downloads and Installation page
2. Once you have downloaded and installed everything, you may wish to try out interactive mode and optionally configure TeXnicCenter to use Asymptote, as described on the Interactive Mode page
3. Look over Basics and skim through Reference or Examples to learn the basics of Asymptote coding.
4. Make a bunch of images!

If you wish to go on and become an Asymptote master, the sections on Advanced Configuration, Logical Operators and Loops, and Macros and Packages are essential.

The Asymptote manual, containing more detailed and advanced instructions, can be found at http://asymptote.sourceforge.net/asymptote.pdf

If you’re a problem solver, be sure to check out the Olympiad package!

Next: Download and Install

NOTE: The following instructions assume that you are using a Windows machine. Instructions for MAC and Unix users can be found under Documentation Installation here.

To begin using Asymptote, you must first download and install it. To view the eps-format images you produce, you will also need to download an eps viewer such as GSview. (GSview is convenient because it can display both eps and pdf files, and with GhostScript installed, Asymptote can easily output the images in pdf format as well.)

Asymptote

To download and install Asymptote on your Windows machine:

1. Click here and wait for the download to begin. This will bring you to SourceForge, which will help you download asymptote-X.YZ-setup.exe, where X.YZ is the version.
2. When the download is complete, browse to D:\downloads\Asymptote, or wherever you saved the file, and double-click on the .exe file (asymptote-X.YZ-setup.exe). This will open an installer window, where you can choose the folder that Asymptote will be installed to (or simply use the default C:\Program Files\Asymptote), and choose whether you wish to have shortcuts added to the desktop and start menu. When you have finished, click Install.

Asymptote is ready to start producing images, but you still need a way to view these images. (NOTE: if you already have a previewer capable of viewing .eps and .pdf files, you do not need to download the file below.)

GSview

GSview is a standard viewer for .eps files, which is the standard output format for Asymptote images. To download and install GSview,

1. Go to this download site, and click on the “Obtaining GSView” link. Then click on the first link down, gsvXYw32.exe, where X.Y is the version. A download window will pop up in your browser. Choose to save the file, and take note of where on your hard drive you saved it to. Let’s say you saved it to the folder D:\downloads\Ghostscript. (If you are unable to get the file gsvXYw32.exe from this site, try this site instead.)
2. When the download is complete, browse to D:\downloads\Ghostscript in your files and double-click on the .exe file gsvXYw32.exe. This will bring you to an installation window. Click Setup.
3. After it extracts the necessary files, there will be a new installation window. Click Next twice, and there will be two checkboxes, which can set GSview to be the default eps or pdf previewer. If you wish to use the more common Acrobat Reader, or some other pdf reader, to view pdf files, only leave the first box checked. However, you can check both if desired.
4. Click Next, and choose the directory in which you want GSview installed (or leave the default setting, C:\Program Files\Ghostgum).
5. Click Next twice, and choose the Start Menu folder to which a shortcut will be added. (The default is Ghostgum.)
6. Click Finish, and GSview will be installed.

Ghostscript

Ghostscript may also need to be installed on your system. You may download it here by clicking on the second link down, GPL Ghostscript. Then, click on the first link down, and copy the file to your computer. After that, run it to install Ghostscript. You may then need to set the version of Ghostscript in GSview. Do this by choosing the Easy Configure option in the Options menu in GSview.

You now have installed everything you need to use Asymptote on the most basic level, as described in the next section.

Next: Interactive Mode

At this point, you are ready to use Asymptote in “Interactive Mode”:

1. Click on the Asymptote icon or run the program asy.exe. You will see a black window, prompting you with a > sign.
2. Type:
   • draw((0,0)--(100,100));
3. Press Enter again, and GSview should pop up, displaying a diagonal line about 1.3 inches in length. (The command drew the path connecting points (0,0) and (100,100) in Cartesian coordinates; to learn more about points, paths, and the draw command, see the Basics section.)

One can continue to use Asymptote in this interactive mode, with each new draw or label command adding something to the diagram. However, this is horribly inefficient. In order to use Asymptote efficiently, it is best to use a powerful editor such as TeXnicCenter (see Art of Problem Solving’s [instructions] in the LaTeX guide) or Crimson Editor to write files containing code for an entire diagram in Asymptote, and compile the file with Asymptote. There are many ways to do this, and many such editors available, but this guide will explain how to configure TeXnicCenter to quickly compile your Asymptote code, in order to be consistent with Art of Problem Solving’s LaTeX guide.

Using TeXnicCenter for Asymptote

First, download and install TeXnicCenter according to the instructions given [here]. Now, use the following steps to set up TeXnicCenter to compile your Asymptote file with the press of a button:

1. Go to the Tools menu, and click Customize.
2. You will see a tab at the top of the Customize window that says Tools. Click on this tab.
3. Click on the New (Insert) button – the one that looks like a dotted rectangle with a star – to create a new Tool. Name the tool whatever you like, say Asymptote.
4. Click on your newly created Asymptote tool. There are three information blocks to fill in:
   1. In the Command block, type in "C:\Program Files\Asymptote\asy.exe" (with the quotes, to ensure that it is a single file name) if you used the default installation folder, or browse to the directory in which you installed Asymptote in order to enter the full path name of asy.exe.
   2. In the Arguments block, type or copy-and-paste the following line:
      • -batchView -tex "latex" %tc
      • This tells Asymptote to produce and view an eps file given the corresponding Asymptote code in your current document.
   3. In the Initial directory block, type %dc.
5. Now you will want to make a shortcut key, or hotkey, to run this tool. Click on the Keyboard tab in the Customize window.
6. Set the Category to Tools, and your Asymptote tool will appear. Click on Asymptote and then on the Press New Shortcut Key block. Then press Alt+A (or any other convenient shortcut key that you wish to use), and click Assign.

Congratulations! You are now ready to create your first Asymptote document.

To do so, create a new file in TeXnicCenter and save it as test.asy. Type the following code into the document:

draw((0,0)--(100,100));
draw((0,100)--(100,0));
dot((50,50));
label("$P$",(50,50),S);

Finally, save the file and press Alt+A (or whatever hot key you assigned in step 6 above), and you should see the following image:

If you wish to include such images directly inside your LaTeX documents, see the section under Advanced Configuration on LaTeX.

Now for the fun part – you are ready to learn the Asymptote language and produce beautiful figures!

Next: Learn Asymptote!

Syntax

On the AoPS forums, you must start the Asymptote diagram with the [asy] tag and end with the [/asy] tag. Each command in Asymptote must be seperated by a semicolon (;). This tells Asymptote where each command ends. For example, the command draw(A--B) draws a line segment from point to given as coordinate pairs. Thus, if you wanted to draw two line segments, say one of them from (0,0) to (50,50) (in units of PostScript points – see below for the explanation of units and size) and the other from (50,0) to (0,50), you can create the following document:

draw((0,0)--(50,50));
draw((0,50)--(50,0));

The two commands do not need to be on separate lines; it is the semicolon that separates them. However, putting the commands on separate lines does not change the output, so it is often useful to separate your commands in this way in order to organize your code. Whitespaces before and after commands are also not read by Asymptote, so any line can be indented as far as desired for clarity’s sake.

To write comments in your code that do not affect the output at all, simply start a line with two forward slashes: // as in

// The following line is drawn from (0,0) to (50,50)
draw((0,0)--(50,50));

Multi-line comment can be declared with /* and ending in */.

/* The  
following line 
is drawn from 
(0,0) to (50,50) */
draw((0,0)--(50,50));

This is useful for finding where your mistakes are because you can comment out parts, and if it has a mistake, then the diagram will not produce an error.

Variables and Data Types

Asymptote parses your code into substrings which have a certain data type, for example a real (like ) or a pair (like ). Each new variable that you declare must be declared as a data type that Asymptote recognizes, by the command [datatype] [variable];. For example, if you wanted to declare the variable to have type integer, you can use the command

 int n;

After it is declared, you can store a specific value in a variable using the symbol, as in

 n=3;

These two commands can be abbreviated by the single command int n=3;, and several integers can also be declared at once (int m,n,d;) or even many declarations and assignations at once: int a,b=2,c,d=5;.

As another example of variable declaration, consider the picture of the X from the Syntax section above. The same picture can be made as follows:

   pair A,B,C,D;
   A=(0,0);
   B=(50,50);
   C=(0,50);
   D=(50,0);
   draw(A--B);
   draw(C--D);

In this particular example, variable declarations made the code longer, but as you will see, declaring variables will significantly clean up your code in messier diagrams.

The most commonly used data types in Asymptote are given in the following table:

Size and Unitsize

Asymptote is a primarily coordinate-based graphics language. Each point is a pair where is the -coordinate and is the -coordinate.

However, there are many ways to choose a Cartesian coordinate system for the plane; one must pick the placement of origin and the scale on each of the – and -axes. Asymptote will place your image in the center of your output page after it is drawn, so placement of origin is actually irrelevant. By default, the unit length in both the and directions is the PostScript bigpoint, which has length inches. Thus, if you do not change the scaling on the picture, the points and are exactly one inch apart when drawn in Asymptote. However, drawing in bigpoints is inconvenient if you wish to draw a figure that is exactly 3cm wide.

The function unitsize can be used to specify the unit length for your picture. This function takes up to 3 arguments: the picture you want to scale the axes for (if this isn’t specified, it defaults to currentpicture, the picture you are drawing on), the unit length in the x direction, and the unit length in the y direction. If only one real argument is given, both the x and y unit sizes are set to this number. Thus the command

unitsize(72);

will tell Asymptote that from now on, your unit length is inch. Be careful when you are redefining your unit length – now that unitsize is set to , the points and are actually inches apart!

Asymptote has the built-in constants pt (1/72.27 inches), inch, cm, and mm for convenience when defining lengths, so the above command can also be stated

unitsize(1inch);

The other useful function is size, which specifies the exact width and height of the box that your picture (if unspecified as a first argument, this will again default to currentpicture) will be fit into. If only one number is given, both the width and the height will be set to this number. For example, the command

size(5cm,5cm);

or just

size(5cm);

will fit the diagram to a 5cm x 5cm box regardless of the specified unitsizes.

As an example, make an Asymptote document containing the following two lines:

unitsize(2inch); 
draw(unitsquare);

and see what happens as you change the inch size to several other values.
Next: Drawing

For more complicated examples, which are often quite neat, see this page in the Art of Problem Solving Test Forum, which has various diagrams from contests. Clicking on them will reveal the code used to make them, so this is an excellent resource for students looking to make more advanced diagrams.
For each of the following, we have put a blue dot at the origin in order to indicate relative location of the output on the coordinate plane. In other words, assume that before each of the examples below is the command

dot((0,0),blue);

In addition, a comment after a line such as //math - extension indicates that the command (in this case extension) used in that line is defined in the math package, thus motivating the import math; (or other appropriate package) line at the top of the example.

Example 1:

dot((20,0));

Output 1:

Example 2:

draw((0,0)--(50,0),BeginArrow);
draw((0,-10)--(50,-10),MidArrow);
draw((0,-20)--(50,-20),EndArrow);
draw((0,-30)--(50,-30),Arrows);

Output 2:

Example 3:

draw((0,0)--(50,0));
arrow((30,0),dir(180),green);

Output 3:

Example 4:

import math;
pair A,B,C,D,E;
A=(0,0); C=(50,0); B=(10,10); D=(40,20);
E=extension(A,B,C,D);  // math - extension
// extension(A,B,C,D) returns the intersection of lines AB and CD
draw(A--B); draw(C--D);
draw(B--E--D,orange);

Output 4:

Example 5:

import graph;
draw(Circle((0,0),20)); // graph - Circle

Output 5:

Example 6:

path p=(0,0)..(20,15)..(40,-5)..(50,0);
draw(p);
draw(rotate(90)*p,green);
draw(rotate(180,(-5,0))*p,orange);
draw(shift((5,20))*p,magenta);
draw(shift((0,-25))*yscale(1.4)*p,red);

Output 6:

Example 7:

import olympiad;
unitsize(50);
pair A,B,C,O,I;
A=origin; B=2*right; C=1.5*dir(70);
O=circumcenter(A,B,C); // olympiad - circumcenter
I=incenter(A,B,C); // olympiad - incenter
draw(A--B--C--cycle);
dot(O);
dot(I);
draw(circumcircle(A,B,C)); // olympiad - circumcircle
draw(incircle(A,B,C)); // olympiad - incircle
label("$I$",I,W);
label("$O$",O,S);

Output 7:

Example 8:

import three;
unitsize(1cm);
size(50);
currentprojection=orthographic(1/2,-1,1/2); // three - currentprojection, orthographic
draw((0,0,0)--(1,0,0)--(1,1,0)--(0,1,0)--cycle,red);
draw((0,0,0)--(0,0,1));
draw((0,1,0)--(0,1,1));
draw((1,1,0)--(1,1,1));
draw((1,0,0)--(1,0,1));
draw((0,0,1)--(1,0,1)--(1,1,1)--(0,1,1)--cycle,green);

—
Example 9:

import three;
unitsize(1cm);
size(50);
currentprojection=orthographic(1/2,-1,1/2); /* three - currentprojection, orthographic */
draw((0,0,0)--(1,0,0)--(1,1,0)--(0,1,0)--cycle,red);
draw((0,0,0)--(0,0,1));
draw((0,1,0)--(0,1,1));
draw((1,1,0)--(1,1,1));
draw((1,0,0)--(1,0,1));
draw((0,0,1)--(1,0,1)--(1,1,1)--(0,1,1)--cycle,green);

Output 9:

—

Example 10, buildcycle:
fill(buildcycle(curveI,reverse(curveIII),curveII),yellow);


Output 10, buildcycle:
Examples in Forum

Clicking on the images the the forum or on images here in the previous examples will show you as to-copy-and-paste the Asymptote source. (For this you have to be registered at artofproblemsolving.com.)

Triangles, lines, tick marks, angle marks

See Also

Many more Asymptote examples

Next: Macros and Packages

Definitions

You can define your own functions in Asymptote. As an example, let’s say you wanted to make a function called newfunction that takes a pair and a real value as input, and returns the pair . In addition, you want it to simply return the pair if no value of is specified, so you want to default to . The code would be as follows:

 pair newfunction(pair z, real r=0)
 {
  real a,b;
  a=z.x;
  b=z.y;
  return (a+r,b+r);
 }

Put this definition in an asymptote document and then test it using some command like

draw(newfunction((20,30))--newfunction((20,30),30)--(0,0)--cycle);  

See if it works!

Notice that the function must be declared a pair since it returns a pair, and each of the variables must be declared some data type too. The default value of was set to by , and the actual function procedure goes in between {}. To define a function with no output simply put void before the function name. This is the general format for a function definition.

Packages

Asymptote comes with several packages that contain useful functions for various purposes. For example, the package graph.asy contains the function

 Circle(pair p, real r, int n=400);

which is a more accurate circle (having 400 nodes by default) than the built-in circle command. To use this function and others in graph.asy, simply put the command

import graph;

at the top of your Asymptote document. Graph also has more advanced functions such as the ability to Graph a function

You can create your own package by simply creating a new .asy file (say MyMacros.asy) with your own definitions in it, and saving it in the directory in which Asymptote is installed (C:\Program Files\Asymptote by default). Then import MyMacros; in your document, and you’ll be set!

The Olympiad Package

We have created an Olympiad package for Asymptote which includes macros for all the constructions that come up most often in Olympiad geometry problems! You can obtain the package olympiad.asy by clicking here or here (the latter link has a few usage examples).

This package includes the following definitions:

Note: A sequence of variables without type declarations indicates that they are the same type as the variable preceding it. For example, the notation concurrent(pair A, B, C, D, E, F) indicates that all of the variables should have type pair.

* These boolean functions test for equality within ps points in order to avoid approximation errors.

Next: Advanced

These pages cover the more advanced features of Asymptote: advanced configuration options, language features, and Asymptote’s ability to be extended through custom functions, macros, and packages.

• Advanced Configuration
• Logical Operators and Loops
• Macros and Packages

Next: Help

There are two things that Asymptote users commonly would like to do with their figures: make the images output in a different format, and include Asymptote code directly into LaTeX files.

Asymptote uses loops and logical operators that are almost identical to those in C++. Loops are absolutely essential if you want to make diagrams that look like this:

This particular example was produced with the following code:

import graph;
real r=5; 
size(r*cm);
picture smiley;
filldraw(smiley,Circle((0,0),1),yellow,black);
fill(smiley,Circle((-.3,.4),.1),black);
fill(smiley,Circle((.3,.4),.1),black);
draw(smiley,Arc((0,0),.5,-140,-40));
for (int i=0; i<5; ++i)
{
 for (int j=0; j<5; ++j)
 {
  if (floor((i-j)/2)==((i-j)/2))
  {
  add(scale(r/10*cm)*smiley,(i,j));
  }
 }
}

Above, we created a picture called smiley and added it to currentpicture many times using a for loop, as the indices and each ranged from to . Basically, the arguments in the parentheses for the first for loop first declare to be an integer and assign to i the value . Then, if , it executes what is inside the {} brackets and when it is finished, it adds to (++i). This process repeats until the boolean statement has the value false, i.e. 5 times (hence the 5 columns of smileys). The if statement is self-explanatory; if (which checks if and have the same parity or not), then the smiley is added, and if not it skips the brackets that follow.

For more information on logical operators and loops, see [here].

Definitions

You can define your own functions in Asymptote. As an example, let’s say you wanted to make a function called newfunction that takes a pair and a real value as input, and returns the pair . In addition, you want it to simply return the pair if no value of is specified, so you want to default to . The code would be as follows:

 pair newfunction(pair z, real r=0)
 {
  real a,b;
  a=z.x;
  b=z.y;
  return (a+r,b+r);
 }

Put this definition in an asymptote document and then test it using some command like

draw(newfunction((20,30))--newfunction((20,30),30)--(0,0)--cycle);  

See if it works!

Notice that the function must be declared a pair since it returns a pair, and each of the variables must be declared some data type too. The default value of was set to by , and the actual function procedure goes in between {}. To define a function with no output simply put void before the function name. This is the general format for a function definition.

Packages

Asymptote comes with several packages that contain useful functions for various purposes. For example, the package graph.asy contains the function

 Circle(pair p, real r, int n=400);

which is a more accurate circle (having 400 nodes by default) than the built-in circle command. To use this function and others in graph.asy, simply put the command

import graph;

at the top of your Asymptote document. Graph also has more advanced functions such as the ability to Graph a function

You can create your own package by simply creating a new .asy file (say MyMacros.asy) with your own definitions in it, and saving it in the directory in which Asymptote is installed (C:\Program Files\Asymptote by default). Then import MyMacros; in your document, and you’ll be set!

The Olympiad Package

We have created an Olympiad package for Asymptote which includes macros for all the constructions that come up most often in Olympiad geometry problems! You can obtain the package olympiad.asy by clicking here or here (the latter link has a few usage examples).

This package includes the following definitions:

Note: A sequence of variables without type declarations indicates that they are the same type as the variable preceding it. For example, the notation concurrent(pair A, B, C, D, E, F) indicates that all of the variables should have type pair.

* These boolean functions test for equality within ps points in order to avoid approximation errors.

Next: Advanced

Troubleshooting

Problem 1: You have added the Asymptote tool to TeXnicCenter, but when you hit your hotkey, you get an ‘Cannot execute the command’ error.

What might be going on: TeXnicCenter doesn’t see the Asymptote executable.

Possible Solution: Go back to the Tools -> Customize window (click Tools, then Customize in TeXnicCenter). Then, click the Tools tab, then select Asymptote. Instead of cutting and pasting the text for the Command line, click the … button after the Command entry box. Then, navigate to the asy.exe executable. You’ll probably have to go up several levels to C:, then click Program Files, then Asymptote, then the file asy with the stylized red A next to it.
Problem 2: I have everything installed and the hotkey doesn’t give me an error in TeXnicCenter, but when I hit the hotkey to compile my code, all that happens is that a window flashes briefly then disappears. Nothing else seems to happen.

What might be going on: Your file is saved as a .tex file, not a .asy file. (TeXnicCenter will even make it look like it’s an .asy file, but it’s really saved as an .asy.tex file.)

Solution: Click file, then Save As, then type your filename with the .asy extension (such as test.asy), the set the ‘Save as type’ field to ‘All files’. This should make it a .asy file.

If this does not work then (for Windows XP) go to My Computer, Tools, Folder Options…, File Types. Click on New and type ASY, then OK. Making sure that the file type ASY is highlighted, click the Change button to the right of “Opens with:”. From here go to browse and find the Asymptote executable program file click Open then OK. Now, retry the File, Save As extension change method outlined above.

It would also help to show file extensions so that file.tex, file.asy, file.pdf aren’t all listed in Explorer and Save boxes as file.

Show File Extension in Windows XP gives a simple walkthrough to show how to do this.
Problem 3: You can draw images with Asymptote, but it doesn’t compile your file whenever you have a label containing LaTeX code (for example, the line label("",(50,50),S); as in test.asy.)

What might be going on: Either Asymptote is not finding your LaTeX compiler, or you have installed your TeX distribution (such as MikTeX) in a folder that Asymptote cannot find.

Solution: Let’s say you installed miktex in the folder C:\Program Files\MiKTeX 2.6 (the default). (If you have a different version of MiKTeX, change the 2.6 to the appropriate number. Look in C:\Program Files for the MiKTeX directory to see what this number should be.) Then there should be a subfolder miktex, containing the folder bin, which contains your latex compiler. When Asymptote is run, it looks for a file called config.asy in the folder C:\Documents and Settings\%USERNAME%\.asy\ where %USERNAME% is your Windows user name. (In Windows Vista, this folder is C:\Users\%USERNAME%\.asy\, where %USERNAME% is your Windows username.) Double-click on the .asy folder, right click and choose New Text Document. This will create a file called New Text Document.txt. Right-click on this file to rename it as config.asy, then open this file with Notepad or a similar editor. Type or copy-and-paste the following lines into the document:

import settings;
texpath="C:\Program Files\MiKTeX 2.6\miktex\bin";
dvips="C:\Program Files\MiKTeX 2.6\miktex\bin\dvips";

When you have finished, save the file config.asy.

As mentioned in the solution to Problem 1, you must make sure that the config.asy file is an ASY file, and not a TXT file that is named config.asy. Look in the File Type column in the Details view to see what type of file config.asy is. If your regular text editor insists on making config.asy a TXT document, use TeXnicCenter to create config.asy.
Problem 4: You run Asymptote and get error: could not load module 'plain'.

What might be going on: Asymptote cannot find the files it needs to run. It may need telling which directory it is installed in.

Solution: You need to create or edit the config.asy file. See the solution to Problem 3 for how to find or create it. Assuming that Asymptote is installed at C:\Program Files\Asymptote then

a) if you already have a config.asy file add the following line somewhere after “import settings;”:

dir="C:\Program Files\Asymptote";

or

b) if you have created a new config.asy file then add the following lines:

import settings;
dir="C:\Program Files\Asymptote";

See the note at the end of Problem 3 regarding creating config.asy.
Problem 4b: You run Asymptote and get
error: could not load module 'plain'
error: could not load module 'file'.

What might be going on: Asymptote does not like file names that contain spaces.

Solution: Replace all spaces in the file name with underscores.
Problem 5: Asymptote suddenly starts misbehaving giving strange errors, going into infinite loops, and not recognizing standard package commands.

What might be going on: A file with the same name as one of the standard package files (like graph.asy or math.asy) was created either by you or by in your working directory or some other directory which Asymptote searches before going to its own directory, so that file is imported instead of the package file.

Prevention: Never name your asy or tex files graph.asy, math.tex and such (these two names seem to be the most common)

Solution: Find all extra files with the same name as standard packages and either .asy or .tex extension and rename or delete them.

External Sources

The following are excellent resources on Asymptote for topics not covered in this guide:

• The Asymptote home page
• Asymptote documentation
• Asymptote FAQ
• Asymptote forum

Next: Useful functions

Intersection points

pair[] intersectionpoints(path, path);

Examples:

size(8cm,0);
import math;
import graph;
real r,s;
pair a,b, common;
path circ1, circ2;
r=1; s=1;
a=(0,0);
b=(1,0);
circ1=circle(a,r);
circ2=circle(b,s);
draw(circ1,linewidth(1bp));
draw(circ2,1bp+green);
pair [] x=intersectionpoints(circ1, circ2);
dot(x[0],3bp+blue);
dot(x[1],3bp+blue);
draw(x[0] -- x[1],1bp+red);

path g=(-3,-sqrt(3))--(3,-sqrt(3))--(0,2*sqrt(3))--cycle;
draw(g,black);
path p=-2/3*(-3,-sqrt(3))--(-2/3)*(3,-sqrt(3))--(-2/3)*(0,2*sqrt(3))--cycle;
draw(p,black);
pair [] x=intersectionpoints(g, p);
fill(x[0]--x[1]--x[2]--x[3]--x[4]--x[5]--cycle,black);
dot((0,0),white);

Note that this function will cause an error if the paths involved do not intersect.
Next: CSE5

The Asymptote CSE5 package is another package that is supported on the AoPS forum. You can download it here. The original idea for writing CSE5 was to enable writing terse codes for complicated pictures. Also some commands in CSE5 (like IP()) work slightly better than the standard Asymptote routines in some cases (the typical example is finding the intersection point of a circle and a tangent line). At last, CSE5 allows to handle some runtime errors like an attempt to find an intersection point of two paths without common points, which may be useful if you try to draw a picture just from its verbal description and do not want to make any calculations beforehand. CSE5 contains doubles of each function; a function with a full name and a function with an abbreviated name.